Contract Address Details

// File: @openzeppelin/contracts/utils/Context.sol

// SPDX-License-Identifier: MIT

pragma solidity >=0.6.0 <0.8.0;

/*
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with GSN meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address payable) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes memory) {
        this; // silence state mutability warning without generating bytecode - see https://github.com/ethereum/solidity/issues/2691
        return msg.data;
    }
}

// File: @openzeppelin/contracts/token/ERC20/IERC20.sol



pragma solidity >=0.6.0 <0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `recipient`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `sender` to `recipient` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address sender, address recipient, uint256 amount) external returns (bool);

    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);
}

// File: @openzeppelin/contracts/math/SafeMath.sol



pragma solidity >=0.6.0 <0.8.0;

/**
 * @dev Wrappers over Solidity's arithmetic operations with added overflow
 * checks.
 *
 * Arithmetic operations in Solidity wrap on overflow. This can easily result
 * in bugs, because programmers usually assume that an overflow raises an
 * error, which is the standard behavior in high level programming languages.
 * `SafeMath` restores this intuition by reverting the transaction when an
 * operation overflows.
 *
 * Using this library instead of the unchecked operations eliminates an entire
 * class of bugs, so it's recommended to use it always.
 */
library SafeMath {
    /**
     * @dev Returns the addition of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function tryAdd(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        uint256 c = a + b;
        if (c < a) return (false, 0);
        return (true, c);
    }

    /**
     * @dev Returns the substraction of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function trySub(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        if (b > a) return (false, 0);
        return (true, a - b);
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, with an overflow flag.
     *
     * _Available since v3.4._
     */
    function tryMul(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
        // benefit is lost if 'b' is also tested.
        // See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522
        if (a == 0) return (true, 0);
        uint256 c = a * b;
        if (c / a != b) return (false, 0);
        return (true, c);
    }

    /**
     * @dev Returns the division of two unsigned integers, with a division by zero flag.
     *
     * _Available since v3.4._
     */
    function tryDiv(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        if (b == 0) return (false, 0);
        return (true, a / b);
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers, with a division by zero flag.
     *
     * _Available since v3.4._
     */
    function tryMod(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        if (b == 0) return (false, 0);
        return (true, a % b);
    }

    /**
     * @dev Returns the addition of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `+` operator.
     *
     * Requirements:
     *
     * - Addition cannot overflow.
     */
    function add(uint256 a, uint256 b) internal pure returns (uint256) {
        uint256 c = a + b;
        require(c >= a, "SafeMath: addition overflow");
        return c;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting on
     * overflow (when the result is negative).
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b) internal pure returns (uint256) {
        require(b <= a, "SafeMath: subtraction overflow");
        return a - b;
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, reverting on
     * overflow.
     *
     * Counterpart to Solidity's `*` operator.
     *
     * Requirements:
     *
     * - Multiplication cannot overflow.
     */
    function mul(uint256 a, uint256 b) internal pure returns (uint256) {
        if (a == 0) return 0;
        uint256 c = a * b;
        require(c / a == b, "SafeMath: multiplication overflow");
        return c;
    }

    /**
     * @dev Returns the integer division of two unsigned integers, reverting on
     * division by zero. The result is rounded towards zero.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b) internal pure returns (uint256) {
        require(b > 0, "SafeMath: division by zero");
        return a / b;
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * reverting when dividing by zero.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b) internal pure returns (uint256) {
        require(b > 0, "SafeMath: modulo by zero");
        return a % b;
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, reverting with custom message on
     * overflow (when the result is negative).
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {trySub}.
     *
     * Counterpart to Solidity's `-` operator.
     *
     * Requirements:
     *
     * - Subtraction cannot overflow.
     */
    function sub(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b <= a, errorMessage);
        return a - b;
    }

    /**
     * @dev Returns the integer division of two unsigned integers, reverting with custom message on
     * division by zero. The result is rounded towards zero.
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {tryDiv}.
     *
     * Counterpart to Solidity's `/` operator. Note: this function uses a
     * `revert` opcode (which leaves remaining gas untouched) while Solidity
     * uses an invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function div(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b > 0, errorMessage);
        return a / b;
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers. (unsigned integer modulo),
     * reverting with custom message when dividing by zero.
     *
     * CAUTION: This function is deprecated because it requires allocating memory for the error
     * message unnecessarily. For custom revert reasons use {tryMod}.
     *
     * Counterpart to Solidity's `%` operator. This function uses a `revert`
     * opcode (which leaves remaining gas untouched) while Solidity uses an
     * invalid opcode to revert (consuming all remaining gas).
     *
     * Requirements:
     *
     * - The divisor cannot be zero.
     */
    function mod(uint256 a, uint256 b, string memory errorMessage) internal pure returns (uint256) {
        require(b > 0, errorMessage);
        return a % b;
    }
}

// File: @openzeppelin/contracts/token/ERC20/ERC20.sol



pragma solidity >=0.6.0 <0.8.0;




/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 * For a generic mechanism see {ERC20PresetMinterPauser}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.zeppelin.solutions/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * We have followed general OpenZeppelin guidelines: functions revert instead
 * of returning `false` on failure. This behavior is nonetheless conventional
 * and does not conflict with the expectations of ERC20 applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 *
 * Finally, the non-standard {decreaseAllowance} and {increaseAllowance}
 * functions have been added to mitigate the well-known issues around setting
 * allowances. See {IERC20-approve}.
 */
contract ERC20 is Context, IERC20 {
    using SafeMath for uint256;

    mapping (address => uint256) private _balances;

    mapping (address => mapping (address => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;
    uint8 private _decimals;

    /**
     * @dev Sets the values for {name} and {symbol}, initializes {decimals} with
     * a default value of 18.
     *
     * To select a different value for {decimals}, use {_setupDecimals}.
     *
     * All three of these values are immutable: they can only be set once during
     * construction.
     */
    constructor (string memory name_, string memory symbol_) public {
        _name = name_;
        _symbol = symbol_;
        _decimals = 18;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5,05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the value {ERC20} uses, unless {_setupDecimals} is
     * called.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual returns (uint8) {
        return _decimals;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual override returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view virtual override returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `recipient` cannot be the zero address.
     * - the caller must have a balance of at least `amount`.
     */
    function transfer(address recipient, uint256 amount) public virtual override returns (bool) {
        _transfer(_msgSender(), recipient, amount);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual override returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 amount) public virtual override returns (bool) {
        _approve(_msgSender(), spender, amount);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20}.
     *
     * Requirements:
     *
     * - `sender` and `recipient` cannot be the zero address.
     * - `sender` must have a balance of at least `amount`.
     * - the caller must have allowance for ``sender``'s tokens of at least
     * `amount`.
     */
    function transferFrom(address sender, address recipient, uint256 amount) public virtual override returns (bool) {
        _transfer(sender, recipient, amount);
        _approve(sender, _msgSender(), _allowances[sender][_msgSender()].sub(amount, "ERC20: transfer amount exceeds allowance"));
        return true;
    }

    /**
     * @dev Atomically increases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function increaseAllowance(address spender, uint256 addedValue) public virtual returns (bool) {
        _approve(_msgSender(), spender, _allowances[_msgSender()][spender].add(addedValue));
        return true;
    }

    /**
     * @dev Atomically decreases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `spender` must have allowance for the caller of at least
     * `subtractedValue`.
     */
    function decreaseAllowance(address spender, uint256 subtractedValue) public virtual returns (bool) {
        _approve(_msgSender(), spender, _allowances[_msgSender()][spender].sub(subtractedValue, "ERC20: decreased allowance below zero"));
        return true;
    }

    /**
     * @dev Moves tokens `amount` from `sender` to `recipient`.
     *
     * This is internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * Requirements:
     *
     * - `sender` cannot be the zero address.
     * - `recipient` cannot be the zero address.
     * - `sender` must have a balance of at least `amount`.
     */
    function _transfer(address sender, address recipient, uint256 amount) internal virtual {
        require(sender != address(0), "ERC20: transfer from the zero address");
        require(recipient != address(0), "ERC20: transfer to the zero address");

        _beforeTokenTransfer(sender, recipient, amount);

        _balances[sender] = _balances[sender].sub(amount, "ERC20: transfer amount exceeds balance");
        _balances[recipient] = _balances[recipient].add(amount);
        emit Transfer(sender, recipient, amount);
    }

    /** @dev Creates `amount` tokens and assigns them to `account`, increasing
     * the total supply.
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     */
    function _mint(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: mint to the zero address");

        _beforeTokenTransfer(address(0), account, amount);

        _totalSupply = _totalSupply.add(amount);
        _balances[account] = _balances[account].add(amount);
        emit Transfer(address(0), account, amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`, reducing the
     * total supply.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     * - `account` must have at least `amount` tokens.
     */
    function _burn(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: burn from the zero address");

        _beforeTokenTransfer(account, address(0), amount);

        _balances[account] = _balances[account].sub(amount, "ERC20: burn amount exceeds balance");
        _totalSupply = _totalSupply.sub(amount);
        emit Transfer(account, address(0), amount);
    }

    /**
     * @dev Sets `amount` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     */
    function _approve(address owner, address spender, uint256 amount) internal virtual {
        require(owner != address(0), "ERC20: approve from the zero address");
        require(spender != address(0), "ERC20: approve to the zero address");

        _allowances[owner][spender] = amount;
        emit Approval(owner, spender, amount);
    }

    /**
     * @dev Sets {decimals} to a value other than the default one of 18.
     *
     * WARNING: This function should only be called from the constructor. Most
     * applications that interact with token contracts will not expect
     * {decimals} to ever change, and may work incorrectly if it does.
     */
    function _setupDecimals(uint8 decimals_) internal virtual {
        _decimals = decimals_;
    }

    /**
     * @dev Hook that is called before any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * will be to transferred to `to`.
     * - when `from` is zero, `amount` tokens will be minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens will be burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(address from, address to, uint256 amount) internal virtual { }
}

// File: @openzeppelin/contracts/token/ERC20/ERC20Burnable.sol



pragma solidity >=0.6.0 <0.8.0;



/**
 * @dev Extension of {ERC20} that allows token holders to destroy both their own
 * tokens and those that they have an allowance for, in a way that can be
 * recognized off-chain (via event analysis).
 */
abstract contract ERC20Burnable is Context, ERC20 {
    using SafeMath for uint256;

    /**
     * @dev Destroys `amount` tokens from the caller.
     *
     * See {ERC20-_burn}.
     */
    function burn(uint256 amount) public virtual {
        _burn(_msgSender(), amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`, deducting from the caller's
     * allowance.
     *
     * See {ERC20-_burn} and {ERC20-allowance}.
     *
     * Requirements:
     *
     * - the caller must have allowance for ``accounts``'s tokens of at least
     * `amount`.
     */
    function burnFrom(address account, uint256 amount) public virtual {
        uint256 decreasedAllowance = allowance(account, _msgSender()).sub(amount, "ERC20: burn amount exceeds allowance");

        _approve(account, _msgSender(), decreasedAllowance);
        _burn(account, amount);
    }
}

// File: @openzeppelin/contracts/GSN/Context.sol



pragma solidity >=0.6.0 <0.8.0;

// File: contracts/utils/DoubleOwnable.sol



pragma solidity ^0.6.12;


/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract DoubleOwnable is Context {
    address private _primaryOwner;
    address private _secondaryOwner;

    event PrimaryOwnershipTransferred(address indexed previousOwner, address indexed newOwner);
    event SecondaryOwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor () public {
        address msgSender = _msgSender();
        _primaryOwner = msgSender;
        emit PrimaryOwnershipTransferred(address(0), msgSender);
    }

    /**
     * @dev Returns the address of the current primary owner.
     */
    function primaryOwner() public view virtual returns (address) {
        return _primaryOwner;
    }

    /**
     * @dev Returns the address of the current secondary owner.
     */
    function secondaryOwner() public view virtual returns (address) {
        return _secondaryOwner;
    }

    /**
     * @dev Throws if called by any account other than the primary owner.
     */
    modifier onlyPrimaryOwner() {
        require(primaryOwner() == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Throws if called by any account other than the both owners.
     */
    modifier onlyOwner() {
        require(primaryOwner() == _msgSender() || secondaryOwner() == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyPrimaryOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyPrimaryOwner {
        emit PrimaryOwnershipTransferred(_primaryOwner, address(0));
        _primaryOwner = address(0);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferPrimaryOwnership(address newOwner) public virtual onlyPrimaryOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        emit PrimaryOwnershipTransferred(_primaryOwner, newOwner);
        _primaryOwner = newOwner;
    }

    /**
     * @dev Set secondary ownership of the contract to a new account (`newOwner`).
     * Can only be called by the primary owner.
     */

    function setSecondaryOwnership(address newOwner) public virtual onlyPrimaryOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        emit SecondaryOwnershipTransferred(_secondaryOwner, newOwner);
        _secondaryOwner = newOwner;
    }
}

// File: contracts/owner/DoubleOperator.sol



pragma solidity ^0.6.0;



contract DoubleOperator is Context, DoubleOwnable {
    address private _primaryOperator;
    address private _secondaryOperator;

    event PrimaryOperatorTransferred(
        address indexed previousOperator,
        address indexed newOperator
    );
    event SecondaryOperatorTransferred(
        address indexed previousOperator,
        address indexed newOperator
    );

    constructor() internal {
        _primaryOperator = _msgSender();
        emit PrimaryOperatorTransferred(address(0), _primaryOperator);
    }

    function primaryOperator() public view returns (address) {
        return _primaryOperator;
    }

    function operator() public view returns (address) {
        return _secondaryOperator;
    }

    modifier onlyDoubleOperator() {
        require(
            (_primaryOperator == msg.sender || _secondaryOperator == msg.sender),
            'operator: caller is not the operator'
        );
        _;
    }

    modifier onlySecondaryOperator() {
        require(
            _secondaryOperator == msg.sender,
            'operator: caller is not the operator'
        );
        _;
    }

    function isOperator() public view returns (bool) {
        return _msgSender() == _primaryOperator || _msgSender() == _secondaryOperator;
    }

    function transferPrimaryOperator(address newOperator_) public onlyPrimaryOwner {
        _transferPrimaryOperator(newOperator_);
    }

    function _transferPrimaryOperator(address newOperator_) internal {
        require(
            newOperator_ != address(0),
            'operator: zero address given for new operator'
        );
        emit PrimaryOperatorTransferred(address(0), newOperator_);
        _primaryOperator = newOperator_;
    }

    function setSecondaryOperator(address newOperator_) external onlyPrimaryOwner {
        require(
            newOperator_ != address(0),
            'operator: zero address given for new operator'
        );

        emit SecondaryOperatorTransferred(address(0), newOperator_);
        _secondaryOperator = newOperator_;
    }
}

// File: contracts/interfaces/IOracle.sol

pragma solidity ^0.6.0;

interface IOracle {
    function update() external;

    function consult(address token, uint256 amountIn)
        external
        view
        returns (uint256 amountOut);
    // function getReserves() external view returns (uint112 reserve0, uint112 reserve1, uint32 blockTimestamp);
}

// File: contracts/interfaces/IPancakePair.sol



pragma solidity 0.6.12;

interface IPancakePair {
    function token0() external view returns (address);
    function token1() external view returns (address);
}

// File: contracts/interfaces/IMoneyPot.sol



pragma solidity =0.6.12;

interface IMoneyPot {
    function updateReceived(uint _amount) external;
    function updateMilestoneOf(address _of) external;
    function updategCASHBonusShare(address _account) external;
    function getRewardToken() external returns (address);
    function newHolder(address _from, uint _amount) external;
    function lessHolder(address _from, uint _amount) external;
    function transferHolder(address _from, address _to, uint256 _amount) external;
}

// File: contracts/interfaces/IDFIMasterChef.sol



pragma solidity =0.6.12;

interface IDFIMasterChef {
    function updategCASHAmount(address[] calldata _of) external;
}

// File: contracts/lib/ExternalCalls.sol



pragma solidity ^0.6.12;




contract ExternalsCalls is DoubleOperator {
    /* ========== EXTERNALS =========== */

    bool public updateMoneyPot; // if true, gCASH will update money pot at each token movement
    bool public updateDFIMasterChef; // if true, gCASH will update DFIANCE master chef at each token movement
    IMoneyPot public moneyPotContract;
    IDFIMasterChef public dfiMasterChefContract;

    function setMoneyPotUpdate(bool _updateMoneyPot) external onlyDoubleOperator {
        if (_updateMoneyPot) {
            require(address(moneyPotContract) != address(0));
        }
        updateMoneyPot = _updateMoneyPot;
    }

    function setDFIMasterChefUpdate(bool _updateDFIMasterChef) external onlyDoubleOperator {
        if (_updateDFIMasterChef) {
            require(address(dfiMasterChefContract) != address(0));
        }
        updateDFIMasterChef = _updateDFIMasterChef;
    }

    function setMoneyPot(address _moneyPot) public onlyDoubleOperator {
        if (updateMoneyPot) {
            require(_moneyPot != address(0));
        }
        moneyPotContract = IMoneyPot(_moneyPot);
    }

    function setMasterChef(address _masterChef) public onlyDoubleOperator {
        if (updateDFIMasterChef) {
            require(_masterChef != address(0));
        }
        dfiMasterChefContract = IDFIMasterChef(_masterChef);
    }

    function _updateExternalContracts(address sender, address recipient) public {
        // update dfiance money pot and master chef

        if (updateMoneyPot) { 
            // inform the money pot of gCASH token possible movement
            moneyPotContract.updategCASHBonusShare(sender);
            moneyPotContract.updategCASHBonusShare(recipient);
        }
        if (updateDFIMasterChef) {
            address[] memory _addressToUpdate = new address[](2);
            _addressToUpdate[0] = sender;
            _addressToUpdate[1] = recipient;

            // verify that the user still holds enough gCASH to stay in DFIANCE master chef pools
            dfiMasterChefContract.updategCASHAmount(_addressToUpdate);
        }
    }
}




pragma solidity 0.6.12;

contract gCASH is ERC20Burnable, DoubleOperator, ExternalsCalls {
    using SafeMath for uint256;

    /* ========== STATE VARIABLES ========== */

    // Fees
    uint256 constant public maxPriceTaxRates = 15e17;
    uint256 constant public minPriceTaxRates = 6e17;
    uint256 constant public gCASHMultiplierStepExpansion = 10e16; // 10 cents
    //list of fees for every price range
    mapping(uint256 => uint256) private feesTaxRate;
    uint256 public lockRatio = 70;
    //list of addresses which exclude fees
    mapping(address => bool) public senderExcludedAddresses;
    mapping(address => bool) public recipientExcludedAddresses;
    mapping(address => bool) public feesIncludedPools; // list of address (of pools) where fees are applied
    mapping(address => bool) public blacklistUsers;

    // Oracle
    address public gCASHOracle;
    address public gCASH;
    address public injector;

    /* ========== CONSTRUCTOR ========== */

    constructor() public ERC20('gCASH', 'gCASH') {
        _mint(msg.sender, 10001 * 10**18);
        // Set the array of tax rate according to the price

        // sub 0.6 = 30%
        feesTaxRate[0] = 15;
        // 0.6 - 0.7 = 29 %
        feesTaxRate[1] = 10;
        // 0.7 - 0.8 = 27 %
        feesTaxRate[2] = 5;
        // 0.8 - 0.9 = 26%
        feesTaxRate[3] = 1; 
        // 0.9 - 1.0 = 25%
        feesTaxRate[4] = 1;
        // 1.0 - 1.1 = 8 %
        feesTaxRate[5] = 1;
        // 1.1 - 1.2 = 6 %
        feesTaxRate[6] = 1;
        // 1.2 - 1.3 = 4%
        feesTaxRate[7] = 1;
        // 1.3 - 1.4 = 3%
        feesTaxRate[8] = 1;
        // 1.4 - 1.5 = 2%
        feesTaxRate[9] = 1;
        // above 1.5 = 1%
        feesTaxRate[10] = 1;
    }

    /* ========== FEES ========== */

    modifier whitelist(address who) {
        require(blacklistUsers[who] == false, "You have been gCASH-ed, no printeri-no.");
        _;
    }

    function addBlacklist(address _blacklist) external onlyDoubleOperator {
        require(_blacklist != address(0), "Can't blacklist 0x addr");
        require(blacklistUsers[_blacklist] == false, "Already blacklisted");
        blacklistUsers[_blacklist] = true;
    }

    function removeBlacklist(address _blacklist) external onlyDoubleOperator {
        require(_blacklist != address(0), "Can't de-blacklist 0x addr");
        require(blacklistUsers[_blacklist] == true, "Not blacklisted yet");
        blacklistUsers[_blacklist] = false;
    }

    // Check the mapping for excluded addresses with fees (Treasury/Boardroom)
    // ==> Fees do not apply to the core algorithm.
    function isSenderExcludedAddresses(address _address) public view returns(bool isIndeed) {
        return senderExcludedAddresses[_address];
    }

    // Add an address to the exluded mapping
    function addSenderExcludedAddresses(address newAddress) public onlyDoubleOperator returns(bool) {
        require(!isSenderExcludedAddresses(newAddress));
        senderExcludedAddresses[newAddress] = true;
        return true;
    }

    // Removes an address from the excluded mapping
    function removeSenderExcludedAddresses(address oldAddress) public onlyDoubleOperator returns(bool) {
        require(isSenderExcludedAddresses(oldAddress));
        senderExcludedAddresses[oldAddress] = false;
        return true;
    }

    // Get fees for a price range (index) :
    function getfeesTaxRate(uint256 index) public view returns(uint256) {
        return feesTaxRate[index];
    }

    // Set fees for a price range (index) :
    function setfeesTaxRate(uint256 index, uint256 fees) public onlyDoubleOperator {
        require(fees <= 40);
        feesTaxRate[index] = fees;
    }

    function setfeesLockRate(uint256 _lockRatio) public onlyDoubleOperator {
        require(_lockRatio < 99, "Too high, ser!");
        lockRatio = _lockRatio;
    }

    function getLockRatio() public view returns(uint256) {
        return lockRatio;
    }

    // Return number of times over the cents step (gCASHMultiplierStepExpansion) :
    function _countTimesOverCents() internal view returns (uint256) {
        uint256 gCASHPrice = getgCASHPrice();
        if (gCASHPrice >= maxPriceTaxRates) {
            return 10;
        } else if (gCASHPrice <= minPriceTaxRates) {
            return 0;
        } else {
            uint256 count;
            gCASHPrice = gCASHPrice.sub(minPriceTaxRates);
            count = gCASHPrice.div(gCASHMultiplierStepExpansion);
            return count.add(1);
        }
    }

    //---------------- RECIPIENT -------------------//

    function isRecipientExcludedAddresses(address _address) public view returns(bool isIndeed) {
        return recipientExcludedAddresses[_address];
    }

    // Add an address to the exluded mapping
    function addRecipientExcludedAddresses(address newAddress) public onlyDoubleOperator returns(bool) {
        require(!isRecipientExcludedAddresses(newAddress));
       recipientExcludedAddresses[newAddress] = true;
        return true;
    }

    // Removes an address from the excluded mapping
    function removeRecipientExcludedAddresses(address oldAddress) public onlyDoubleOperator returns(bool) {
        require(isRecipientExcludedAddresses(oldAddress));
        recipientExcludedAddresses[oldAddress] = false;
        return true;
    }

    function addFeesIncludedPools(address pool) external onlyDoubleOperator returns(bool) {
        require(feesIncludedPools[pool] == false);
        feesIncludedPools[pool] = true;
        return true;
    }

    function removeFeesIncludedPools(address pool) external onlyDoubleOperator returns(bool) {
        require(feesIncludedPools[pool]);
        feesIncludedPools[pool] = false;
        return true;
    }

    /* ========== ORACLE ========== */

    // Set new Oracle on the gCASH contract
    function setgCASHOracleAddress(address newOracle) public onlyDoubleOperator {
        gCASHOracle = newOracle;
    }
    // Reference the gCASH address to itself as an argument for the Oracle
    function setgCASHAddress(address newgCASHAddress) public onlyDoubleOperator {
        gCASH = newgCASHAddress;
    }

    function setInjectorAddress(address newInjector) public onlyDoubleOperator {
        injector = newInjector;
    }

    /* ========== MAIN FUNCTIONS ========== */

    function mint(address recipient_, uint256 amount_) public onlySecondaryOperator returns (bool) {
        uint256 balanceBefore = balanceOf(recipient_);
        _mint(recipient_, amount_);
        uint256 balanceAfter = balanceOf(recipient_);

        address[] memory _recipient = new address[](1);
        _recipient[0] = recipient_;

        if (updateMoneyPot) moneyPotContract.updategCASHBonusShare(recipient_); // inform the money pot of gCASH token possible movement
        if (updateDFIMasterChef) dfiMasterChefContract.updategCASHAmount(_recipient); // verify that the user still holds enough gCASH to stay in DFIANCE master chef pools

        return balanceAfter > balanceBefore;
    }

    // try to execute function "getter" and return value (=> used to return token0 and token1 from DEX pools)
    function getPoolToken(address pool, string memory signature, function() external view returns(address) getter) private returns (address token) {
        (bool success, ) = pool.call(abi.encodeWithSignature(signature)); // if the call succeed (pool address have the "signature" method or "pool" is an EOA)
        if (success) {
            uint32 size;
            assembly {
                size := extcodesize(pool)
            }
            if (size > 0) { // verify that the pool is a contract (constructor can bypass this but its not dangerous)
                return getter();
            }
        }
    }

    // check if the recipient is a liquidity pool with gCASH into
    function isgCASHLiquidityPool(address recipient) public returns (bool) {
        address token0 = getPoolToken(recipient, "token0()", IPancakePair(recipient).token0);
        address token1 = getPoolToken(recipient, "token1()", IPancakePair(recipient).token1);

        return (feesIncludedPools[recipient] || token0 == address(this) || token1 == address(this));
    }


    function transferFrom(address sender, address recipient, uint256 amount) public whitelist(sender) override returns (bool) {
        _transferOverride(sender, recipient, amount);
        _approve(sender, _msgSender(), allowance(sender, _msgSender()).sub(amount, "Drip Drip, ERC20: transfer amount exceeds allowance"));
        _updateExternalContracts(sender, recipient);

        return true;
    }    

    function transfer(address recipient, uint256 amount) public whitelist(_msgSender()) override returns (bool) {
        _transferOverride(_msgSender(), recipient, amount);
        _updateExternalContracts(_msgSender(), recipient);

        return true;
    }

    function _transferOverride(address sender, address recipient, uint256 amount) internal returns (bool) {
        // if the recipient is a liquidity pool with gCASH, its a gCASH sell => take fees
        if ((isSenderExcludedAddresses(sender) == false && isRecipientExcludedAddresses(recipient) == false) && isgCASHLiquidityPool(recipient)) {
            uint feesAmount = amount.mul(feesTaxRate[_countTimesOverCents()]).div(100); // 
            uint feesForLiquidity = feesAmount.mul(lockRatio).div(100);
            uint feesForBurn = feesAmount.sub(feesForLiquidity);
        
            super._burn(sender, feesForBurn);
            _transfer(sender, injector, feesForLiquidity);
            
            _transfer(sender, recipient, amount.sub(feesAmount));
        } else { // else, if the call comes from a contract, => transfer with fees :
            _transfer(sender, recipient, amount);
        }

        return true;
    }

    function burn(uint256 amount) public virtual override {
        _burn(_msgSender(), amount);

        address[] memory _sender = new address[](1);
        _sender[0] = _msgSender();

        if (updateMoneyPot) moneyPotContract.updategCASHBonusShare(_msgSender()); // inform the money pot of gCASH token possible movement
        if (updateDFIMasterChef) dfiMasterChefContract.updategCASHAmount(_sender); // verify that the user still holds enough gCASH to stay in DFIANCE master chef pools
    }

    /* ========== GET FUNCTIONS ========== */

    function getgCASHPrice() public view returns (uint256 gCASHPrice) {
        try IOracle(gCASHOracle).consult(gCASH, 1e18) returns (uint256 price) {
            return price;
        } catch {
            revert("Failed to consult gCASH price from the oracle");
        }
    }
}